sp {propose*wander
   (state <s> ^name tanksoar
             -^sound
              ^io.input-link <io>)
   (<io> -^radar.tank
        -^incoming.<dir> yes)
-->
   (<s> ^operator.name wander)
}

sp {propose*attack
   (state <s> ^name tanksoar
              ^io.input-link.radar.tank
             -^missiles-energy low)
   -->
   (<s> ^operator <o> + =)
   (<o> ^name attack)}

sp {propose*chase
   (state <s> ^name tanksoar
              ^sound
             -^io.input-link.radar.tank
             -^missiles-energy low)
   -->
   (<s> ^operator.name chase)}

# If the state is tanksoar and the sound sensor 
# is not silent or there is a tank on radar or there is an 
# incoming missile, and health is low or the energy is low, 
# then propose the retreat operator.

sp {propose*retreat*sound
   (state <s> ^name tanksoar
              ^missiles-energy low
              ^sound)
   -->
   (<s> ^operator <o> + =)
   (<o> ^name retreat)}

sp {propose*retreat*radar
   (state <s> ^name tanksoar
              ^missiles-energy low
              ^io.input-link.radar.tank)
   -->
   (<s> ^operator <o> + =)
   (<o> ^name retreat)}

sp {propose*retreat*incoming
   (state <s> ^name tanksoar
              ^missiles-energy low
              ^io.input-link.incoming.<dir> yes)
   -->
   (<s> ^operator <o> + =)
   (<o> ^name retreat)}

# If the state is tanksoar and the tanks is under 
# attack but cannot not directly sense the other tank, 
# then propose the retreat operator.

sp {propose*retreat*incoming*not-sensed
   (state <s> ^name tanksoar
             -^sound
              ^io.input-link <io>)
   (<io> ^incoming.<dir> yes
        -^radar.tank)
   -->
   (<s> ^operator <o> + =)
   (<o> ^name retreat)}