### Rules to create a 365-day calendar.
### This version creates all 365 days.

sp {initialize*calendar
    (state <s> ^superstate nil)
	-->                                       
    (<s> ^year <y>)
    (<y> ^value 2003)}

sp {initialize*months
    (state <s> ^year <y>)
	-->
    (<y> ^month <m1>)
    (<m1> ^name january)
    (<y> ^month <m2>)
    (<m2> ^name february)
    (<y> ^month <m3>)
    (<m3> ^name march)
    (<y> ^month <m4>)
    (<m4> ^name april)
    (<y> ^month <m5>)
    (<m5> ^name may)
    (<y> ^month <m6>)
    (<m6> ^name june)
    (<y> ^month <m7>)
    (<m7> ^name july)
    (<y> ^month <m8>)
    (<m8> ^name august)
    (<y> ^month <m9>)
    (<m9> ^name september)
    (<y> ^month <m10>)
    (<m10> ^name october)
    (<y> ^month <m11>)
    (<m11> ^name november)
    (<y> ^month <m12>)
    (<m12> ^name december)}

sp {initialize*31day*length
    (state <s> ^year <y>)
    (<y> ^month <m>)
    (<m> ^name << january march may july august october december >> )
	-->
    (<m> ^days 31)}

sp {initialize*30day*length
    (state <s> ^year <y>)
    (<y> ^month <m>)
    (<m> ^name << september april june november >> )
	-->
    (<m> ^days 30)}

sp {initialize*february*length
    (state <s> ^year <y>)
    (<y> ^month <m>)
    (<m> ^name february)
	-->
    (<m> ^days 28)}

sp {initialize*first*days
    (state <s> ^year <y>)
    (<y> ^month <m>)
	-->
    (<m> ^date 1)}

sp {initialize*remaining*days
    (state <s> ^year <y>)
    (<y> ^month <m>)
    (<m> ^days <len>)
    (<m> ^date { <d> < <len> } )
	-->
    (<m> ^date ( + <d> 1 ))}