### Rules to create a 365-day calendar.
### This version uses dot notation.

sp {initialize*calendar
    (state <s> ^superstate nil)
	-->                                       
    (<s> ^year <y>)
    (<y> ^value 2003)}

sp {initialize*months
    (state <s> ^year <y>)
	-->
    (<y> ^month.name january)
    (<y> ^month.name february)
    (<y> ^month.name march)
    (<y> ^month.name april)
    (<y> ^month.name may)
    (<y> ^month.name june)
    (<y> ^month.name july)
    (<y> ^month.name august)
    (<y> ^month.name september)
    (<y> ^month.name october)
    (<y> ^month.name november)
    (<y> ^month.name december)}

sp {initialize*31day*length
    (state <s> ^year.month <m>)
    (<m> ^name << january march may july august october december >> )
	-->
    (<m> ^days 31)}

sp {initialize*30day*length
    (state <s> ^year.month <m>)
    (<m> ^name << september april june november >> )
	-->
    (<m> ^days 30)}

### Note that <m> is needed in the following rule and cannot be
### replaced by a dot.
sp {initialize*february*length
    (state <s> ^year.month <m>)
    (<m> ^name february)
	-->
    (<m> ^days 28)}

sp {initialize*first*days
    (state <s> ^year.month <m>)
	-->
    (<m> ^date 1)}

### Note that <m> is needed in the following rule and cannot be
### replaced by a dot.
sp {initialize*remaining*days
    (state <s> ^year.month <m>) 
    (<m> ^days <len>)
    (<m> ^date { <d> < <len> } )
	-->
    (<m> ^date ( + <d> 1 ))}