# Print the sudoku board one row at a time.

sp {init*printing
   (state <s> ^name print-board)
-->
   (<s> ^row-printed 0)
   (write (crlf) )}

sp {propose*print*row
   (state <s> ^name print-board
              ^row-printed { <n> < 9 } )
-->
   (<s> ^operator <o> + = )
   (<o> ^name print-row
        ^row ( + 1 <n> ))}

sp {apply*print*row
   (state <s> ^name print-board
              ^superstate.board <b>
              ^row-printed <prev>
              ^operator <o>)
   (<o> ^name print-row
        ^row <row>)
   (<b> ^square <s1> <s2> <s3> <s4> <s5> <s6> <s7> <s8> <s9>)
   (<s1> ^row <row> ^column 1 ^contents <c1>)
   (<s2> ^row <row> ^column 2 ^contents <c2>)
   (<s3> ^row <row> ^column 3 ^contents <c3>)
   (<s4> ^row <row> ^column 4 ^contents <c4>)
   (<s5> ^row <row> ^column 5 ^contents <c5>)
   (<s6> ^row <row> ^column 6 ^contents <c6>)
   (<s7> ^row <row> ^column 7 ^contents <c7>)
   (<s8> ^row <row> ^column 8 ^contents <c8>)
   (<s9> ^row <row> ^column 9 ^contents <c9>)
-->
   (write (crlf) | [ | <c1> | | <c2> | | <c3> | ][ | <c4> | | <c5> | | <c6> | ][ | <c7> | | <c8> | | <c9> | ] | )
   (<s> ^row-printed <row> <prev> - )}

sp {propose*terminate*printing
   (state <s> ^name print-board)
-->
   (<s> ^operator <o> + < = )
   (<o> ^name terminate-printing)}

sp {apply*terminate*printing
   (state <s> ^name print-board
              ^superstate.board <b>
              ^operator <o>)
   (<o> ^name terminate-printing)
   (<b> ^print yes)
-->
   (<b> ^print yes - ) #take off the printing flag
   (write (crlf) )
}