# Create the board. Link together the squares.
sp {create-sudoku-board
   (state <s> ^superstate nil)
-->
   (<s> ^board <b>)
   (<b> ^square <s11> <s12> <s13> <s14> <s15> <s16> <s17> <s18> <s19>
        ^square <s21> <s22> <s23> <s24> <s25> <s26> <s27> <s28> <s29>
        ^square <s31> <s32> <s33> <s34> <s35> <s36> <s37> <s38> <s39>
        ^square <s41> <s42> <s43> <s44> <s45> <s46> <s47> <s48> <s49>
        ^square <s51> <s52> <s53> <s54> <s55> <s56> <s57> <s58> <s59>
        ^square <s61> <s62> <s63> <s64> <s65> <s66> <s67> <s68> <s69>
        ^square <s71> <s72> <s73> <s74> <s75> <s76> <s77> <s78> <s79>
        ^square <s81> <s82> <s83> <s84> <s85> <s86> <s87> <s88> <s89>
        ^square <s91> <s92> <s93> <s94> <s95> <s96> <s97> <s98> <s99>)
   (<s11> ^right <s12> ^down <s21> ^row 1 ^column 1) #first row
   (<s12> ^right <s13> ^left <s11> ^down <s22> ^row 1 ^column 2)
   (<s13> ^right <s14> ^left <s12> ^down <s23> ^row 1 ^column 3)
   (<s14> ^right <s15> ^left <s13> ^down <s24> ^row 1 ^column 4)
   (<s15> ^right <s16> ^left <s14> ^down <s25> ^row 1 ^column 5)
   (<s16> ^right <s17> ^left <s15> ^down <s26> ^row 1 ^column 6)
   (<s17> ^right <s18> ^left <s16> ^down <s27> ^row 1 ^column 7)
   (<s18> ^right <s19> ^left <s17> ^down <s28> ^row 1 ^column 8)
   (<s19> ^left <s18> ^down <s29> ^row 1 ^column 9)
   (<s21> ^right <s22> ^down <s31> ^up <s11> ^row 2 ^column 1) #second row
   (<s22> ^right <s23> ^left <s21> ^down <s32> ^up <s12> ^row 2 ^column 2)
   (<s23> ^right <s24> ^left <s22> ^down <s33> ^up <s13> ^row 2 ^column 3)
   (<s24> ^right <s25> ^left <s23> ^down <s34> ^up <s14> ^row 2 ^column 4)
   (<s25> ^right <s26> ^left <s24> ^down <s35> ^up <s15> ^row 2 ^column 5)
   (<s26> ^right <s27> ^left <s25> ^down <s36> ^up <s16> ^row 2 ^column 6)
   (<s27> ^right <s28> ^left <s26> ^down <s37> ^up <s17> ^row 2 ^column 7)
   (<s28> ^right <s29> ^left <s27> ^down <s38> ^up <s18> ^row 2 ^column 8)
   (<s29> ^left <s28> ^down <s39> ^up <s19> ^row 2 ^column 9)
   (<s31> ^right <s32> ^down <s41> ^up <s21> ^row 3 ^column 1) #third row
   (<s32> ^right <s33> ^left <s31> ^down <s42> ^up <s22> ^row 3 ^column 2)
   (<s33> ^right <s34> ^left <s32> ^down <s43> ^up <s23> ^row 3 ^column 3)
   (<s34> ^right <s35> ^left <s33> ^down <s44> ^up <s24> ^row 3 ^column 4)
   (<s35> ^right <s36> ^left <s34> ^down <s45> ^up <s25> ^row 3 ^column 5)
   (<s36> ^right <s37> ^left <s35> ^down <s46> ^up <s26> ^row 3 ^column 6)
   (<s37> ^right <s38> ^left <s36> ^down <s47> ^up <s27> ^row 3 ^column 7)
   (<s38> ^right <s39> ^left <s37> ^down <s48> ^up <s28> ^row 3 ^column 8)
   (<s39> ^left <s38> ^down <s49> ^up <s29> ^row 3 ^column 9)
   (<s41> ^right <s42> ^down <s51> ^up <s31> ^row 4 ^column 1) #fourth row
   (<s42> ^right <s43> ^left <s41> ^down <s52> ^up <s32> ^row 4 ^column 2)
   (<s43> ^right <s44> ^left <s42> ^down <s53> ^up <s34> ^row 4 ^column 3)
   (<s44> ^right <s45> ^left <s43> ^down <s54> ^up <s34> ^row 4 ^column 4)
   (<s45> ^right <s46> ^left <s44> ^down <s55> ^up <s35> ^row 4 ^column 5)
   (<s46> ^right <s47> ^left <s45> ^down <s56> ^up <s36> ^row 4 ^column 6)
   (<s47> ^right <s48> ^left <s46> ^down <s57> ^up <s37> ^row 4 ^column 7)
   (<s48> ^right <s49> ^left <s47> ^down <s58> ^up <s38> ^row 4 ^column 8)
   (<s49> ^left <s48> ^down <s59> ^up <s39> ^row 4 ^column 9)
   (<s51> ^right <s52> ^down <s61> ^up <s41> ^row 5 ^column 1) #fifth row
   (<s52> ^right <s53> ^left <s51> ^down <s62> ^up <s42> ^row 5 ^column 2)
   (<s53> ^right <s54> ^left <s52> ^down <s63> ^up <s43> ^row 5 ^column 3)
   (<s54> ^right <s55> ^left <s53> ^down <s64> ^up <s44> ^row 5 ^column 4)
   (<s55> ^right <s56> ^left <s54> ^down <s65> ^up <s45> ^row 5 ^column 5)
   (<s56> ^right <s57> ^left <s55> ^down <s66> ^up <s46> ^row 5 ^column 6)
   (<s57> ^right <s58> ^left <s56> ^down <s67> ^up <s47> ^row 5 ^column 7)
   (<s58> ^right <s59> ^left <s57> ^down <s68> ^up <s48> ^row 5 ^column 8)
   (<s59> ^left <s58> ^down <s69> ^up <s49> ^row 5 ^column 9)
   (<s61> ^right <s62> ^down <s71> ^up <s51> ^row 6 ^column 1) #sixth row
   (<s62> ^right <s63> ^left <s61> ^down <s72> ^up <s52> ^row 6 ^column 2)
   (<s63> ^right <s64> ^left <s62> ^down <s73> ^up <s53> ^row 6 ^column 3)
   (<s64> ^right <s65> ^left <s63> ^down <s74> ^up <s54> ^row 6 ^column 4)
   (<s65> ^right <s66> ^left <s64> ^down <s75> ^up <s55> ^row 6 ^column 5)
   (<s66> ^right <s67> ^left <s65> ^down <s76> ^up <s56> ^row 6 ^column 6)
   (<s67> ^right <s68> ^left <s66> ^down <s77> ^up <s57> ^row 6 ^column 7)
   (<s68> ^right <s69> ^left <s67> ^down <s78> ^up <s58> ^row 6 ^column 8)
   (<s69> ^left <s68> ^down <s79> ^up <s59> ^row 6 ^column 9)
   (<s71> ^right <s72> ^down <s81> ^up <s61> ^row 7 ^column 1) #seventh row
   (<s72> ^right <s73> ^left <s71> ^down <s82> ^up <s62> ^row 7 ^column 2)
   (<s73> ^right <s74> ^left <s72> ^down <s83> ^up <s63> ^row 7 ^column 3)
   (<s74> ^right <s75> ^left <s73> ^down <s84> ^up <s64> ^row 7 ^column 4)
   (<s75> ^right <s76> ^left <s74> ^down <s85> ^up <s65> ^row 7 ^column 5)
   (<s76> ^right <s77> ^left <s75> ^down <s86> ^up <s66> ^row 7 ^column 6)
   (<s77> ^right <s78> ^left <s76> ^down <s87> ^up <s67> ^row 7 ^column 7)
   (<s78> ^right <s79> ^left <s77> ^down <s88> ^up <s68> ^row 7 ^column 8)
   (<s79> ^left <s78> ^down <s89> ^up <s69> ^row 7 ^column 9)
   (<s81> ^right <s82> ^down <s91> ^up <s71> ^row 8 ^column 1) #eighth row
   (<s82> ^right <s83> ^left <s81> ^down <s92> ^up <s72> ^row 8 ^column 2)
   (<s83> ^right <s84> ^left <s82> ^down <s93> ^up <s73> ^row 8 ^column 3)
   (<s84> ^right <s85> ^left <s83> ^down <s94> ^up <s74> ^row 8 ^column 4)
   (<s85> ^right <s86> ^left <s84> ^down <s95> ^up <s75> ^row 8 ^column 5)
   (<s86> ^right <s87> ^left <s85> ^down <s96> ^up <s76> ^row 8 ^column 6)
   (<s87> ^right <s88> ^left <s86> ^down <s97> ^up <s77> ^row 8 ^column 7)
   (<s88> ^right <s89> ^left <s87> ^down <s98> ^up <s78> ^row 8 ^column 8)
   (<s89> ^left <s88> ^down <s99> ^up <s79> ^row 8 ^column 9)
   (<s91> ^right <s92> ^up <s81> ^up <s81> ^row 9 ^column 1) #ninth row
   (<s92> ^right <s93> ^left <s91> ^up <s82> ^up <s83> ^row 9 ^column 2)
   (<s93> ^right <s94> ^left <s92> ^up <s83> ^up <s83> ^row 9 ^column 3)
   (<s94> ^right <s95> ^left <s93> ^up <s84> ^up <s84> ^row 9 ^column 4)
   (<s95> ^right <s96> ^left <s94> ^up <s85> ^up <s85> ^row 9 ^column 5)
   (<s96> ^right <s97> ^left <s95> ^up <s86> ^up <s86> ^row 9 ^column 6)
   (<s97> ^right <s98> ^left <s96> ^up <s87> ^up <s87> ^row 9 ^column 7)
   (<s98> ^right <s99> ^left <s97> ^up <s88> ^up <s88> ^row 9 ^column 8)
   (<s99> ^left <s98> ^up <s89> ^up <s89> ^row 9 ^column 9)}

# Copy puzzle numbers to the squares.
sp {elaborate*init*puzzle
   (state <s> ^board.square <sq>
              ^puzzle <puzzle>)
   (<sq> ^row <row> ^column <col>)
   (<puzzle> ^value (^row <row>
                     ^column <col>
                     ^contents <contents>) )
-->
   (<sq> ^contents <contents>)}

# Fill blanks in empty puzzle squares.
sp {elaborate*init*puzzle*blanks
   (state <s> ^board.square <sq>
              ^puzzle <puzzle>)
   (<sq> ^row <row> ^column <col>)
 - (<puzzle> ^value (^row <row>
                     ^column <col>) )
-->
   (<sq> ^contents B)}

# Label each square with the group it's in.
sp {elaborate*group1
   (state <s> ^board.square <sq>)
   (<sq> ^row { <= 3 }
        ^column { <= 3 } )
-->
   (<sq> ^group 1)}

sp {elaborate*group2
   (state <s> ^board.square <sq>)
   (<sq> ^row { <= 3 }
        ^column { >= 4 <= 6 } )
-->
   (<sq> ^group 2)}

sp {elaborate*group3
   (state <s> ^board.square <sq>)
   (<sq> ^row { <= 3 }
        ^column { >= 7 } )
-->
   (<sq> ^group 3)}

sp {elaborate*group4
   (state <s> ^board.square <sq>)
   (<sq> ^row { >= 4 <= 6 }
        ^column { <= 3 } )
-->
   (<sq> ^group 4)}

sp {elaborate*group5
   (state <s> ^board.square <sq>)
   (<sq> ^row { >= 4 <= 6 }
        ^column { >= 4 <= 6 } )
-->
   (<sq> ^group 5)}

sp {elaborate*group6
   (state <s> ^board.square <sq>)
   (<sq> ^row { >= 4 <= 6 }
        ^column { >= 7 } )
-->
   (<sq> ^group 6)}

sp {elaborate*group7
   (state <s> ^board.square <sq>)
   (<sq> ^row { >= 7 }
        ^column { <= 3 } )
-->
   (<sq> ^group 7)}

sp {elaborate*group8
   (state <s> ^board.square <sq>)
   (<sq> ^row { >= 7 }
        ^column { >= 4 <= 6 } )
-->
   (<sq> ^group 8)}

sp {elaborate*group9
   (state <s> ^board.square <sq>)
   (<sq> ^row { >= 7 }
        ^column { >= 7 } )
-->
   (<sq> ^group 9)}

# Soar needs to know the numbers from 1 to 9.
sp {elaborate*integers*from*1*to*9
   (state <s> ^superstate nil)
-->
   (<s> ^integer 1 2 3 4 5 6 7 8 9 )}

# Basic operator to fill in a number in a blank square.
sp {propose*fill*in*number
   (state <s> ^board <b>
              ^integer <int>)
   (<b> ^square <sq>)
   (<sq> ^contents B
        ^row <row> ^column <col> ^group <gp>)
 - { (<b> ^square <s2>) #if this number is not already on the same row
     (<s2> ^row <row> ^contents <int>) }
 - { (<b> ^square <s3>) #if this number is not already on the same column 
     (<s3> ^column <col> ^contents <int>) }
 - { (<b> ^square <s4>) #if this number is not already in the same group
     (<s4> ^group <gp> ^contents <int>) }
-->
   (<s> ^operator <o> + = )
   (<o> ^name fill-in
        ^square <sq>
        ^value <int>)}

sp {apply*fill*in*number
   (state <s> ^operator <o>
              ^board <b>)
   (<o> ^name fill-in
        ^square <sq>
        ^value <int>)
   (<sq> ^contents B
         ^row <row> ^column <col>)
-->
   (write (crlf) | Putting number | <int> | into row: | <row> | column: | <col> )
   (<sq> ^contents <int> B - ) #change the number
   (<b> ^print yes) #set the printing flag
}

#sp {propose*print*board
#   (state <s> ^board.print yes)
#-->
#   (<s> ^operator <o> + > = )
#   (<o> ^name print-board)}

sp {prefer*print*to*fill-in
   (state <s> ^operator <o1> +
              ^operator <o2> + )
   (<o1> ^name print-board)
   (<o2> ^name fill-in)
-->
   (<s> ^operator <o1> > <o2>)}

# Puzzle solved. Print and halt.
sp {propose*halt*success
   (state <s> ^board <b>)
 - (<b> ^square.contents B)
-->
   (<s> ^operator <o> + > = )
   (<o> ^name halt-success)}

sp {apply*halt*success
   (state <s> ^operator.name halt-success)
-->
   (write (crlf) | Puzzle solved! | )
   (halt)}

# Cannot complete this partial solution. Give up.
sp {propose*halt*failure
   (state <s> ^board <b>)
 - { (<s> ^operator <o> + )
     (<o> ^name fill-in) }
   (<b> ^square.contents B)
-->
   (<s> ^operator <o> + = )
   (<o> ^name halt-failure)}

sp {apply*halt*failure
   (state <s> ^operator.name halt-failure)
-->
   (write (crlf) | I failed to solve the puzzle. Sorry. | )
   (halt)}